|
您的位置：学院
>> 编程开发 >>
VB >> VB中使用WinSock控件编写网络程序
|
VB中使用WinSock控件编写网络程序
|
WinSock控件能够通过UDP协议（用户数据报协议）或TCP协议（数据传输协议）连接到远程的机器并进行数据交换。这两种协议都能用来创建客户端和服务端应用程序。就像定时器控件一样，WinSock控件运行时没有一个可视的界面。
可能的用途
创建客户端应用程序，它能在信息到达中央服务器之前把用户的信息收集起来。
创建服务端应用程序，它能作为来自多个用户的数据一个集中处理点。
创建“聊天”程序。
协议的选择
当我们使用WinSock控件时，首先要确定的是使用TCP还是UDP协议。它们之间主要的区别在于连接状态：
TCP协议控件是一个基于连接的协议，就像电话机一样，用户必须在通话之前建立连接；
UDP是一个无连接的协议，两台计算机之间的事务处理就像传纸条一样：一台计算机向另一台计算机发送消息，但是它们之间并没有一个明确的连接路径。另外，发送的单个信息量的大小取决于网络。
通常，你要创建的应用程序的类别就决定了你要选择的协议。以下是几个能够帮助你选择合适的协议的问题：
当发送或接收数据时，该应用程序需要从服务端或客户端获得认证吗？如果要的话，那么TCP协议就正好需要在发送或接受数据前建立明确的连接。
要发送的数据量大吗？（就像图片、声音文件之类）一旦建立了连接，TCP协议就会保持连接并保证数据的完整性。但是，这种连接会占用的更多的处理器资源，成本也会更高一些。
数据是陆续传输的，还是一次全部传完呢？比如，如果你要创建的应用程序在某些任务完成时会告知具体的计算机，那么选择UDP协议会更合适一些。UDP协议也更适合于发送小量数据。
协议的配置
配置你的应用程序所用到的协议：在设计阶段，单击工具窗口里的协议，选择sckTCPProtocol或sckUDPProtocol。你也可以在代码里配置协议，就像下面这样：
Winsock1.Protocol=sckTCPProtocol
确定你的计算机名
要连接到远程的计算机，你必须知道它的IP地址或别名。IP地址是一串用句点分隔的3位数字。通常，计算机的别名更容易让人记住。
按下面的步骤可以找到你的计算机名:
在“任务栏”里单击“开始”
在“设置”选项里单击“控制面板”；
双击“网络”图标；
单击“网络标识”
在“计算机名”中显示的就是你的计算机名。
一旦你找到你的计算名，它就可以作为远程主机的属性来用了。
TCP连接入门
当用TCP控件创建应用程序的时候，必须首先明确你的程序是作为服务端还是客户端。创建服务端程序就意味着你的程序能够在指定的端口进行“监听”，而客户端则能够提出请求，服务端能够接受请求并实现连接。一旦连接建立起来，客户端和服务端就能够自由地进行通信。
创建服务端程序
下面是创建一个简单服务端程序的步骤：
创建一个标准EXE工程；
把默认窗体(Default form)的名字改为frmServer;
把form的标题（caption）改为TCP Server；
把Winsock控件拉到窗体中，并命名为tcpServer；
在窗体中添加2个文本框，分别命名为txtSendData和txtOutput‘
在窗体中加入下列代码；
Private Sub Form_Load()
' Set the LocalPort property to an integer.
' Then invoke the Listen method.
tcpServer.LocalPort = 1001
tcpServer.Listen
frmClient.Show ' Show the client form.
End Sub
Private Sub tcpServer_ConnectionRequest _
(ByVal requestID As Long)
' Check if the control's State is closed. If not,
' close the connection before accepting the new
' connection.
If tcpServer.State <> sckClosed Then _
tcpServer.Close
' Accept the request with the requestID
' parameter.
tcpServer.Accept requestID
End Sub
Private Sub txtSendData_Change()
' The TextBox control named txtSendData
' contains the data to be sent. Whenever the user
' types into the textbox, the string is sent
' using the SendData method.
tcpServer.SendData txtSendData.Text
End Sub
Private Sub tcpServer_DataArrival _
(ByVal bytesTotal As Long)
' Declare a variable for the incoming data.
' Invoke the GetData method and set the Text
' property of a TextBox named txtOutput to
' the data.
Dim strData As String
tcpServer.GetData strData
txtOutput.Text = strData
End Sub |
上面就是创建一个简单的服务端应用程序的过程。然而，要完成整个过程，你还得创建一个客户端程序。
创建TCP客户端程序
在工程中添加一个新的窗体(form)，并命名为frmClient；
将窗体的标题(caption)改为TCP Client；
添加一个Windsock控件到窗体中，命名为tcpCllient；
添加2个文本框控件到frmClient窗体，分别命名为txtSend和txtOutput；
添加一个按钮控件(CommandButton)到窗体，命名为cmdConnecti；
将按钮控件标题(caption)改为Connect；
在窗体中添加下面代码：
注：确保将远程主机属性(RemoteHost property)改为你的计算机别名。
Private Sub Form_Load()
' The name of the Winsock control is tcpClient.
' Note: to specify a remote host, you can use
' either the IP address (ex: "121.111.1.1") or
' the computer's "friendly" name, as shown here.
tcpClient.RemoteHost = "RemoteComputerName"
tcpClient.RemotePort = 1001
End Sub
Private Sub cmdConnect_Click()
' Invoke the Connect method to initiate a
' connection.
tcpClient.Connect
End Sub
Private Sub txtSendData_Change()
tcpClient.SendData txtSend.Text
End Sub
Private Sub tcpClient_DataArrival _
(ByVal bytesTotal As Long)
Dim strData As String
tcpClient.GetData strData
txtOutput.Text = strData
End Sub |
以上代码就能创建一个简单的客/服应用程序。要试着让两者建立连接，可以运行工程，单击Connect。在任意一个txtSendData文本框中输入文本，同样的文本信息就会出现在另一个窗体的txtOutput文本框中出现。
接受多个连接请求
上面介绍的服务端程序智能接受一个连接请求。但是，通过创建一组控件，并使用同样的控件来接受多个连接请求也是可能的。在这种情况下，你不需要关闭连接，只要创建新的控件实例（通过配置它的索引属性），调用新的实例中的接受方法。
下面的代码中，假定在一个叫sckServer的窗体中有一个Winsock控件，它的索引属性设置为0。这样这个控件就是控件数组的一部分。在声明段中，生命一个模块级变量intMax。在窗体的载入事件中，intMax被设置为0，数组中第一个控件的本地端口属性被设置为1001。
监听方法在控件中被调用，它被作为“监听控件”。每个连接请求到来时，代码会测试看它的索引(Index)是否为0（监听控件的值），如果是0，监听控件中intMax值增1，并用这个值创建新的控件实例。新的控件实例被用来接受连接请求。
Private intMax As Long
Private Sub Form_Load()
intMax = 0
sckServer(0).LocalPort = 1001
sckServer(0).Listen
End Sub
Private Sub sckServer_ConnectionRequest _
(Index As Integer, ByVal requestID As Long)
If Index = 0 Then
intMax = intMax + 1
Load sckServer(intMax)
sckServer(intMax).LocalPort = 0
sckServer(intMax).Accept requestID
Load txtData(intMax)
End If
End Sub |
UDP连接入门
创建一个UDP应用程序比创建TCP程序更简单，因为UDP协议不需要一个确定的连接。在上面的TCP应用程序中，其中一个Winsock控件必须明确的被设置为“监听”，而另一个必须用连接方法发起连接。
相反，UDP协议不需要明确的连接。要在2个控件之间传送数据，（连接的双方）必须完成三个步骤：
确定远程主机属性为对方的计算机名；
确定远程主机属性为第二个控件的本地端口属性；
调用约定方法指定要被使用的本地端口。（下面将详细讨论该方法）
创建一个的UDP连接端
创建一个标准EXE工程；
将默认窗体命名为frmPeerA；
在窗体中添加一个Winsock控件，命名为udpPeerA；
在属性(Properties)页，单击协议(Protocol)，改为UDPProtocol；
添加2个文本框控件窗体中，分别命名为txtSend和txtOutput；
在窗体中添加下面代码：
Private Sub Form_Load()
' The control's name is udpPeerA
With udpPeerA
' IMPORTANT: be sure to change the RemoteHost
' value to the name of your computer.
.RemoteHost= "PeerB"
.RemotePort = 1001 ' Port to connect to.
.Bind 1002 ' Bind to the local port.
End With
frmPeerB.Show ' Show the second form.
End Sub
Private Sub txtSend_Change()
' Send text as soon as it's typed.
udpPeerA.SendData txtSend.Text
End Sub
Private Sub udpPeerA_DataArrival _
(ByVal bytesTotal As Long)
Dim strData As String
udpPeerA.GetData strData
txtOutput.Text = strData
End Sub |
创建第二个UDP连接端
添加标准窗体到工程中；
将窗体名改为frmPeerB；
将窗体标题改为Peer B；
在窗体中添加一个Windsock控件并命名为udpPeerB；
在属性页中单击Protocol，改为UDPProtocol；
添加2个文本框到窗体中，分别命名为txtSend和txtOutput；
在窗体中添加下面代码:
Private Sub Form_Load()
' The control's name is udpPeerB.
With udpPeerB
' IMPORTANT: be sure to change the RemoteHost
' value to the name of your computer.
.RemoteHost= "PeerA"
.RemotePort = 1002 ' Port to connect to.
.Bind 1001 ' Bind to the local port.
End With
End Sub
Private Sub txtSend_Change()
' Send text as soon as it's typed.
udpPeerB.SendData txtSend.Text
End Sub
Private Sub udpPeerB_DataArrival _
(ByVal bytesTotal As Long)
Dim strData As String
udpPeerB.GetData strData
txtOutput.Text = strData
End Sub |
关于约定方法
上面代码中所涉及的，在创建UDP应用程序时必须调用约定方法。这个约定的方法保留了控件用到的本地端口。例如，当你绑定控件到端口1001时，其他的应用程序都不能用该端口监听。当你希望阻止其他的应用程序使用某端口的时候，这个就很有用。
这个约定方法也引起了争议。如果机器里有多个网络适配器，本地IP允许你指定用哪个适配器。如果你忽略了这个争议性问题，控件就会使用计算机控制面板设置中，在网络控制面板对话框里列出的第一个网络适配器。
在使用UDP协议时，你可以自由的切换远程主机和远程端口属性，同时保留本地端口范围。但是在使用UDP协议时，你必须在改变远程主机和远程端口属性时关闭连接。
|
|
|
产品库推荐 |
|
